Ход работы. Нажмите клавиши SHIFT+ENTER, затем начинайте набирать новую строку.

Нажмите клавиши SHIFT+ENTER, затем начинайте набирать новую строку.

 

10. Как ввести новую строку в том же абзаце?

Нажмите клавиши SHIFT+ENTER, затем начинайте набирать новую строку.

11. Как заменить автофигуру?

Выберите автофигуру, которую требуется заменить. Нажмите на панели инструментов Рисование кнопку Действия укажите на раздел: Изменить автофигуру и выберите требуемую автофигуру.

 

12. Как настроить показ презентации?

Панель инструментов- Дизайн, Переходы, Анимации, Показ слайдов-настройка времени и тд.

 

13. Как добавить текстовый спецэффект?

Выделить надпись - Переходы, и выбрать тот эффект который нравиться.

 

 

Лабораторная работа № 1 НАПИСАНИЕ МОДУЛЯ, ФОРМИРУЮЩЕГО СУММУ ПРОПИСЬЮ

 

Цель работы: написать программу с использованием MS EXCEL, для автоматического ведения суммы прописью.

В финансовых документах необходимо указывать итоговую сумму прописью, и лучше будет, если эта процедура будет производиться автоматически. Для этого необходимо написать модуль (программу), которая позволяла бы это делать.

Входной информацией для работы программы должно быть числовое значение. В результате работы должны получить представление этого числа прописью.

Ход работы

1. Для начала работы запустите редактор электронных таблиц MS EXCEL.

 

2. В ячейку А1 введите любое число или ссылку на ячейку, в которой находится число, например, в данной задаче мы будем рассматривать число 1 111 111 руб. 11 коп. Весь ход работы и результат можно посмотреть на рис. 1.1.

 

3. Далее необходимо выделить миллионы, сотни, тысячи и единицы, затем разбить соответствующие трехзначные (включая не значащие нули) числа на отдельные цифры.

Для этого введите в ячейки В1 и А2:С4 следующие формулы:

в ячейку В1: =ПРАВСИМВ(“000000000”&ЦЕЛОЕ(А1);9) – эта формула позволяет добавить к сумме девять незначащих нулей слева и затем выделяет девять символов справа;

в ячейку А2: =ЗНАЧЕН(ПСТР(В1;1;1))

в ячейку А3: =ЗНАЧЕН(ПСТР(В1;2;1))

в ячейку А4: =ЗНАЧЕН(ПСТР(В1;3;1))

в ячейку В2: =ЗНАЧЕН(ПСТР(В1;4;1))

в ячейку В3: =ЗНАЧЕН(ПСТР(В1;5;1))

в ячейку В4: =ЗНАЧЕН(ПСТР(В1;6;1))

в ячейку С2: =ЗНАЧЕН(ПСТР(В1;7;1))

в ячейку С3: =ЗНАЧЕН(ПСТР(В1;8;1))

в ячейку С4: =ЗНАЧЕН(ПСТР(В1;9;1))

Формулы в ячейках А2:С4 выделяют поочередно символы и преобразуют их в цифры из полученного текстового значения.

Функция ПРАВСИМВ возвращает заданное число последних знаков текстовой строки. Синтаксис этой функции: ПРАВСИМВ(текст;число_знаков),

где текст – это текстовая строка, содержащая извлекаемые знаки; число_знаков – количество знаков, извлекаемых функцией ПРАВСИМВ.

Рис. 1.1. Исходные данные и результат решения задачи

Функция ПСТР возвращает указанное число знаков из текстовой строки, начиная с указанной позиции.

Синтаксис этой функции ПСТР(текст;начальная_позиция; число_знаков), где текст – это текстовая строка, содержащая извлекаемые знаки; начальная_позиция – позиция первого знака, извлекаемого из текста. Первый знак в тексте имеет начальную позицию 1 и т. д.; число_знаков – указывает, сколько знаков требуется вернуть.

Функция ЗНАЧЕН преобразует строку текста, отображающую число в число.

Синтаксис этой функции ЗНАЧЕН(текст), где текст – текст в кавычках или ссылка на ячейку, содержащую текст, который нужно преобразовать.

 

4. Далее выделите из общей суммы число копеек, которое принято записывать двумя цифрами, например, не 0, а 00, не 2, а 02. Для этого в ячейки С1 и D1 введите следующие формулы:

– в ячейку С1: =ЦЕЛОЕ(А1*100-ЦЕЛОЕ(А1)*100+0,5), эта формула позволяет выделить число копеек из общей суммы (слагаемое 0,5 необходимо для правильного округления);

– в ячейку D1: =ПРАВСИМВ(“0”&ЦЕЛОЕ(С1);2), эта формула позволит добавить, если нужно, знак нуля слева.

Функция ЦЕЛОЕ – округляет число до ближайшего меньшего целого. Синтаксис этой функции ЦЕЛОЕ(число), где число – это вещественное число, округляемое до ближайшего меньшего целого.

5. Далее необходимо написать словами числа миллионов, тысяч и рублей. Для этого введите на своем листе в ячейках А12:Н20 таблицу, приведенную на рис. 1.2. Обратите внимание, что в столбцах D и Е учтены грамматические окончания мужского и женского рода.

Рис. 1.2. Таблица-словарь названий

 

6. Далее необходимо дать имена столбцам. Для этого выделите курсором столбец (например, сотни А12-А20), затем переводите курсор в левую часть строки формул (под панелью инструментов, там, где вы видите номера ячеек), нажмите левую кнопку мыши, введите слово сотни и нажмите клавишу Enter (рис. 1.3).

Рис. 1.3. Ввод названий столбцов

Затем повторите эту операцию для всех столбцов. Удалить неправильно введенное имя можно с помощью окна «Присвоение имени», которое можно активизировать следующим путем: меню Вставка→Имя→Присвоить… (рис. 1.4). В этом окне необходимо выбрать ошибочно введенное имя и нажать кнопку Удалить, после чего повторить приведенную ранее процедуру с присвоением столбцу имени.

Рис. 1.4. Вызов окна «Присвоение имени»

 

7. Далее нужно сделать процедуру, которая поможет складывать названия чисел из цифр. Для этого сначала введите в ячейку А6 следующую формулу (обратите внимание, что формулу нужно набирать в одной строке):

=ЕСЛИ(А2=0;"";ИНДЕКС(сотни;А2;1)&" ")

&ЕСЛИ(И(А3=1;А4<>0);ИНДЕКС(надцать;А4;1);

ЕСЛИ(А3=0;"";ИНДЕКС(десятки;A3;1) &" ")

&ЕСЛИ(А4=0;"";ИНДЕКС(единицым;А4;1)))

Эта формула расшифровывается следующим образом:

если число сотен (А2) равно 0, то к строке ничего не добавлять (""), иначе выбрать в столбце сотни слово, соответствующее сотням, и добавить к нему пробел (" ");

если число десятков (A3) равно 1 и число единиц (А4) не равно 0, то выбрать в столбце надцать слово, соответствующее числу единиц, иначе:

если число десятков (A3) равно 0, то к строке ничего не добавлять (""), иначе выбрать в столбце десятки слово, соответствующее числу десятков и добавить к нему пробел;

если число единиц (А4) равно 0, то к строке ничего не добавлять (""), иначе найти в столбце единицым слово, соответствующее числу единиц.

 

Знак & здесь обозначает конкатенацию, или соединение символов.

Функция И выполняет проверку совпадения условий.

Функция ИНДЕКС возвращает значение или ссылку на значение из таблицы или интервала. Функция ИНДЕКС имеет две синтаксические формы: ссылка и массив. Ссылочная форма всегда возвращает ссылку; форма массива всегда возвращает значение или массив значений.

В данном примере необходимо использовать форму массива, при этом синтаксис функции будет следующим:

ИНДЕКС(массив;номер_строки;номер_столбца), где массив – это диапазон ячеек или массив констант;

номер_строки – это номер строки в массиве, из которой нужно возвращать значение, если номер_строки опущен, то аргумент номер_столбца нужно задавать обязательно;

номер_столбца – это номер столбца в массиве, из которого нужно возвращать значение. Если номер_столбца опущен, то аргумент номер_строки нужно задавать обязательно.

Скопируйте формулу из ячейки А6 (автозаполнением) в ячейки В6 и С6. Соответственно формулы в этих ячейках будут выглядеть следующим образом:

В6:=ЕСЛИ(B2=0;"";ИНДЕКС(сотни;B2;1)&" ")

&ЕСЛИ(И(B3=1;B4<>0);ИНДЕКС(надцать;B4;1);

ЕСЛИ(B3=0;"";ИНДЕКС(десятки;B3;1)&" ")

&ЕСЛИ(B4=0;"";ИНДЕКС(единицым;B4;1)))

С6: =ЕСЛИ(C2=0;"";ИНДЕКС(сотни;C2;1)&" ")

&ЕСЛИ(И(C3=1;C4<>0);ИНДЕКС(надцать;C4;1);

ЕСЛИ(C3=0;"";ИНДЕКС(десятки;C3;1)

&" ")&ЕСЛИ(C4=0;"";ИНДЕКС(единицым;C4;1)))

 

8. Теперь выберите грамматические формы слов миллион, тысяча и рубли. Для этого введите в ячейки А7, В7 и С7 следующие формулы (удобно формулу из ячейки А6 скопировать в В7 и С7, а затем отредактировать):

А7: =ЕСЛИ(ИЛИ(А3=0;А4=1);F12;ИНДЕКС(миллионы;А4;1))

В7: =ЕСЛИ(ИЛИ(В3=0;В4=1);G16;ИНДЕКС(тысячи;В4;1))

С7: =ЕСЛИ(ИЛИ(С3=0;С4=1);Н16;ИНДЕКС(рубли;С4;1))

Смысл формул состоит в следующем: если в трехзначном числе нет единиц (А3=0) или есть числа от 11 до 19 (А4=1), то грамматическая форма соответствует множественному числу (слова миллионов, тысяч, рублей берутся из ячеек F12, G16, H16), иначе необходимо выбрать грамматическую форму слова из соответствующего столбца по числу единиц.

Здесь ИЛИ – функция, получающая значение ИСТИНА, если одно из условий верно.

 

9. Теперь сформируйте сумму прописью. Это выполняется с помощью формулы в ячейке А9 (обратите внимание что формулу нужно набирать в одной строке):

=ЕСЛИ(ДЛСТР(А6)=0;"";А6&" "&А7&" ")

&ЕСЛИ(ДЛСТР(В6)=0;"";B6&" "&B7&" ")

&ЕСЛИ(ДЛСТР(С6)=0;С7;С6&" "&С7)&" "

Эта формула позволяет проверить, есть ли разряды миллионов, тысяч и единиц (длины соответствующих строк не равны нулю), и соединить (с помощью конкатенации) все полученные слова в одно предложение.

 

10. Замените первую букву полученного словосочетания на прописную, а также добавьте число копеек. Все это сделайте с помощью следующей формулы в ячейке А10:

=ПРОПИСН(ЛЕВСИМВ(А9;1))&ПРАВСИМВ(А9;ДЛСТР(А9)-1)&" "& D1&" коп."

Синтаксис этой функции ПРОПИСН(текст), где текст – это текст, преобразуемый в верхний регистр. Текст может быть ссылкой на текст или текстовой строкой.

ЛЕВСИМВ возвращает указанное число знаков с начала текстовой строки, синтаксис этой функции ЛЕВСИМВ(текст; количество_знаков), где текст – текстовая строка, содержащая извлекаемые знаки; количество_знаков – количество знаков, извлекаемых функцией ЛЕВСИМВ.

ДЛСТР возвращает количество знаков в текстовой строке, синтаксис этой функции ДЛСТР(текст), где текст – текст, длину которого нужно определить. Пробелы также учитываются.

Таким образом, в ячейках А1-Н20 теперь находится программа – получения суммы прописью.

 

КОНТРОЛЬНЫЕ ВОПРОСЫ И ЗАДАНИЯ

1. Какая функция возвращает значение или ссылку на значение из таблицы или интервала?

2. Какая функция округляет число до ближайшего меньшего целого?

3. Подготовьте бланк счета за товар по образцу, приведенному на рис. 1.5, и примените программу, полученную в лабораторной работе № 1, для отображения итоговой суммы прописью.

Рис. 1.5. Бланк счета